[Allegro] onfnda99.flx : Finde-Automatik

[Ruth Hübner]

Bernhard Eversberg <ev at biblio.tu-bs.de> hat am 7. Juni 2010 um 09:28
geschrieben:

> Der mitgelieferte  onfnda99.flx  ist sicher nicht das Optimum bzw.
> funktioniert womöglich gar nicht. Frage deshalb: Hat jemand einen
> besseren geschaffen, den wir u.U. mit ins Angebot nehmen können?

Ich habe einen ganz nützlichen einfachen Suchflex, der auf der Grundlage einer
umfassenden Stichwortindexierung im Reg. 2 (das ist ja eigentlich für
Körperschaften gedacht, die werden bei uns aber ganz selten gesucht) gut
funktioniert. Aber meine Versuche, ihn als onfnda99.flx zu benutzen scheitern an
den Umlauten (sicher ein Zeichensatzproblem). Daher habe ich ihn mit kleinen
Modifizierungen bisher als Flip auf der Titelanzeige untergebracht ("Neue
Suche"). Dort gibt es bei uns keine Probleme mit den Umlauten.

Vielleicht kann man daraus "was basteln". Ist für bis zu 5 Suchwörter gebaut.
Wenn mehr Wörter eingegeben werden, macht es aber nichts.

Wenn man einfach das Stichwortregister hernimmt, so wie es standardmäßig
mitgeliefert wird, und mit "tit suchwort ..." sucht, dann ist der Nachteil, dass
der durchaus häufige Fall, dass Personennamen zusammen mit Titelstichwörtern
gesucht werden, nicht abgedeckt ist. 

Denkbar wäre ja, dass die auseinandergenommenen Suchwörter in verschiedener
Kombination in unterschiedlichen Registern gesucht werden, immer wenn kein
Treffer kommt, kann man ja noch was anderes versuchen, aber mir schien das zu
aufwändig und daher habe ich lieber ein Volltextsuchregister erstellt. Dieses
bläht die Indexgröße auch gar nicht so sehr auf, wie ich befürchtet hatte (bei
150.000 Datensätzen wächst cat.adx bei uns nur um ca. 600 KB). 

Schön wäre noch, wenn man Stoppwörter "erkennen" und aussortieren könnte und
wenn man den Index an einer Stelle aufblättern könnte, die z.B. dem ersten
Suchwort entspricht. Konnte ich nicht hinkriegen (Flex-Dilettantin).

Mein onfnda99.flx sieht also so aus:

---

// Suchflex für onfnda99.flx oder anderweitig
// Grundlage umfassendes Stichwortregister Index 2 mit allem, was für relevant 
// gehalten wird
// $RH 20100427

:start
Var ""
ins #uSa
ins #uSb
ins #uSc
ins #uSd
ins #uSe

// Abschnitt für Such-Abfrage ohne Anbindung an onfnda99.flx
// Suchworte abfragen:
// ask Neue Suche? - Artikel (der, die, das, a, le ... usw.) bitte weglassen!
// if "" end
// dann muss die nächste Zeile aber deaktiviert werden!

var #ux0
// und in #uSW speichern 
insert #uSW
var "ket " #uSW(e" ")
ins #uSa
var #uSW(b" " e" ") 
if "" jump mach1
var "and ket " #uSW(b" " e" ") 
ins #uSb
var #uSW(b" " b" " e" ")
if "" jump mach2
var "and ket " #uSW(b" " b" " e" ")
ins #uSc
var #uSW(b" " b" " b" " e" ")
if "" jump mach3
var "and ket " #uSW(b" " b" " b" " e" ")
ins #uSd
var #uSW(b" " b" " b" " b" " e" ")
if "" jump mach4
var "and ket " #uSW(b" " b" " b" " b" " e" ")
ins #uSe
var " " #uSa " " #uSb " " #uSc " " #uSd " " #uSe
asci
find

:zeig
if empty jump nix
order a0\sho list
end

:mach1
var " " #uSa 
asci
find
jump zeig

:mach2
var " " #uSa " " #uSb 
asci
find
jump zeig

:mach3
var " " #uSa " " #uSb " " #uSc 
asci
find
jump zeig

:mach4
var " " #uSa " " #uSb " " #uSc " " #uSd
asci
find
jump zeig

// Anmerkung für Sprungmarke :nix: "Neue Suche?" einbauen, falls nicht an 
// onfnda99.flx, sondern mit eigener Abfrage, dann kann ein Sprung zu :start  
// für neue Suche eingebaut und Meldungstext entspr. angepasst werden

:nix
var "Die Suche nach *" #uSW "* brachte kein Ergebnis." n "Vielleicht hier nichts
vorhanden" n "Im Index nachsehen?"
yesno
if yes ind |1goe
end

---

Eigentlich fände ich es ganz schön, wenn ein Volltextregister mit "einfacher"
Suchfunktion gleich standardmäßig in a99 enthalten wäre, denn so eingeschränkt
die Möglichkeiten dabei auch sind, "die Leser wünschen es sich sehr". Die
anderen Register gibt es ja trotzdem. Am besten würde ich es finden, wenn man
diese Volltextsuche in das Find-Menü einbauen könnte. Als oberste Zeile. Dann
wäre es so, wie es viele aus anderen Bibliothekskatalogen gewöhnt sind.

Beste Grüße aus Berlin
Ruth Hübner
--
Zentrum fuer Literatur- und Kulturforschung
- Bibliothek -
Schuetzenstr. 18
10117 Berlin

Tel.: 030 - 20 192 172 / 122